$ !
$ !                    COPYRIGHT (c) 1991 BY
$ !          DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASSACHUSETTS
$ !                           ALL RIGHTS RESERVED.
$ !
$ !  THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
$ !  ONLY IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE AND WITH THE INCLUSION
$ !  OF THE ABOVE COPYRIGHT NOTICE.  THIS SOFTWARE OR ANY OTHER COPIES
$ !  THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY OTHER
$ !  PERSON.  NO TITLE TO AND OWNERSHIP OF THE SOFTWARE IS HEREBY TRANSFERRED.
$ !
$ !  THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE WITHOUT NOTICE AND
$ !  SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
$ !
$ !  DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY OF ITS
$ !  SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY DIGITAL.
$ !
$!==================================================================================
$GET_VERSION_ID: SUBROUTINE
$!
$  SS7_Vers == 0
$  SS7_Nb_Vers == 0
$  SS7_Vers_List == ""
$FILE_LOOP:
$  SS7_File = F$SEARCH("SYS$SYSTEM:SS7$*_PROTOCOL.DAT")
$  IF SS7_File .eqs. "" THEN GOTO END_FILE_LOOP
$  SS7_Nb_Vers == SS7_Nb_Vers + 1
$  SS7_Tmp = F$EXTRACT(F$LOCATE("SS7$",SS7_File)+4,999,SS7_File)
$  SS7_Tmp = F$EXTRACT(0,F$LOCATE("_PROTOCOL",SS7_TMP),SS7_Tmp)
$  IF P1 .eqs. SS7_Tmp then goto VERSION_ID_FOUND
$  SS7_Vers_List == SS7_Vers_List + ", " + SS7_Tmp
$  GOTO FILE_LOOP
$!
$END_FILE_LOOP:
$  SS7_Vers_List == SS7_Vers_List - ","
$  IF P1 .eqs. ""
$  THEN
$   IF SS7_Nb_Vers .eq. 1 
$   THEN 
$       GOTO VERSION_ID_FOUND
$   ELSE
$       SAY " The following DECss7 versions are installed on the system:"
$	SAY SS7_Vers_List
$	SAY ""
$       SAY " Please select a version and pass it as parameter P2"
$   ENDIF
$  ELSE
$	SAY "%DECSS7-F-VERSNOTINSTAL, The ''p1' DECss7 version is not installed"
$  ENDIF
$  goto END_GET_VERSION_ID
$!
$VERSION_ID_FOUND:
$ SS7_Choosen_Version == SS7_Tmp
$ SS7_Vers == 1
$END_GET_VERSION_ID:
$ENDSUBROUTINE
$!===========================================================================================
$GET_PROTOCOL: SUBROUTINE
$ open/read F1 SYS$SYSTEM:SS7$'SS7_Choosen_Version'_PROTOCOL.DAT
$ read F1 LINE
$ SS7_loc = f$locate("PROT=",F$EDIT(LINE,"UPCASE"))
$ SS7_Prot == f$extract(5,f$length(LINE),LINE)
$ close F1
$END_GET_PROTOCOL:
$ ENDSUBROUTINE
$!==================================================================================
$ Say := Write Sys$Output
$! Verify the parameters
$! P1 : DEB | NODEB
$! P2 : [Version-Id]  (not mandatory if only one version is installed)
$!
$ P1 = F$EDIT(P1,"TRIM,UPCASE")
$ P2 = F$EDIT(P2,"TRIM,UPCASE")
$ Say ""
$ if P1 .nes. "DEB" .and. P1 .nes. "NODEB" then goto BAD_SYNTAX
$ call GET_VERSION_ID 'p2
$ if SS7_Vers .eq. 0 then exit
$PARAM_OK :
$ call GET_PROTOCOL
$ If F$trnlnm("SOURCE",,,,,"VALUE") .eqs. "" Then define/nolog SOURCE SYS$EXAMPLES
$ If F$trnlnm("EXEC",,,,,"VALUE")   .eqs. "" Then define/nolog EXEC   SYS$EXAMPLES
$ Say " Building the VLR main program"
$ Say " For ''SS7_Choosen_Version' DECss7 Version, ''SS7_Prot' protocol"
$ Say ""
$ Say " Source files location   : ''F$trnlnm("SOURCE",,,,,"VALUE")'"
$ Say " Resultant files location: ''F$trnlnm("EXEC",,,,,"VALUE")'"
$ Say ""
$ VLR_NAME = "SS7$VLR_''SS7_Choosen_Version'_MAIN"
$! Get the Architecture type (VAX/Alpha)
$ SS7_arch = f$edit(f$getsyi("arch_name"),"UPCASE")
$ On Error Then exit
$ Write Sys$Output " ... Compiling"
$ If SS7_arch .eqs. "VAX" 
$ Then 
$   ccopt = "/vaxc"
$ Else 
$   ccopt = "/standard=vaxc"
$ Endif
$ Cc'ccopt'/'P1/NoOpt/Obj=EXEC:'VLR_NAME'.OBJ SOURCE:ss7_vlr /define=('SS7_Prot')/include=sys$library:
$ Cc'ccopt'/'P1/NoOpt/Obj=EXEC:ss7$ivp_tools.Obj SOURCE:ss7_ivp_tools/include=sys$library:
$!
$ Write Sys$Output " ... Linking"
$ open/write f1 EXEC:ss7$ivp_'SS7_Choosen_Version'_link.opt
$ If SS7_arch .eqs. "VAX" Then write f1 "sys$share:vaxcrtl.exe/share"
$ write f1 "sys$share:ss7$tcapport_''SS7_Choosen_Version'_shr.exe/share"
$ close f1
$ purge/nolog EXEC:ss7$ivp_'SS7_Choosen_Version'_link.opt
$ Link /'P1 -
	/NoTraceback -
	/Exe= EXEC:'VLR_NAME'.exe -
	EXEC:'VLR_NAME', -
        EXEC:ss7$ivp_tools, -
        EXEC:ss7$ivp_'SS7_Choosen_Version'_link.opt/OPTIONS
$ EXIT:
$ Pur/nolog EXEC:ss7$ivp_tools.obj
$ Pur/nolog EXEC:'VLR_NAME'.obj
$ Pur/nolog EXEC:'VLR_NAME'.exe
$ exit
$BAD_SYNTAX:
$ Say "Usage: SS7$VLR_BUILD  DEB|NODEB  [Version-Id]"
$ exit