$!  LEGACY_BUILD.COM
$!
$!  Command procedure to build the Mega_Zillionare
$!  application in the old fashioned way.  All
$!  files will be placed in the proper directories 
$!  for a production system.
$!
$!  Required parameters:
$!  P1      environment code "D01", "T01", "S01", or "P01"
$!
$ bell[0,7] = %x07
$!
$ say :== WRITE SYS$OUTPUT
$!
$!;;;;;
$!  Make sure user supplied a parameter
$!;;;;;
$ if "''p1'" .eqs. ""
$ then
$   say bell, bell, bell
$   say "you must supply P1 of D01, T01, S01, or P01
$   goto exit_program
$ endif
$!
$!;;;;;
$!  Validate the parameter
$!;;;;;
$ env_str = f$edit( "''p1'", "COLLAPSE,UPCASE")
$ if env_str .eqs. "D01" then goto good_parm
$ if env_str .eqs. "T01" then goto good_parm
$ if env_str .eqs. "S01" then goto good_parm
$ if env_str .eqs. "P01" then goto good_parm
$!
$!   Supplied parameter invalid
$!
$ say bell, bell, bell
$ SAY "you must supply P1 of D01, T01, S01, or P01
$ goto exit_program
$!
$!;;;;;
$!  Make certain we have the correct logicals
$!;;;;;
$good_parm:
$!
$ A = f$trnlnm( "MEGA_COM")
$ if "''a'" .eqs. ""
$ then
$   @dka1200:[mega_'env_str'.cms_ref]mega_environment "''env_str'"
$ else
$   @mega_com:mega_environment "''env_str'"
$ endif
$!
$ set noverify
$!;;;;;;;;;;
$!  Reconstruct CDD
$!;;;;;;;;;;
$ b = f$search( "MEGA_COM:MEGA_REBUILD_CDD.COM")
$!
$ show symbol b
$ if "''b'" .les. ""
$ then
$   @mega_src:mega_rebuild_cdd
$ else
$   @mega_com:mega_rebuild_cdd.com
$ endif
$!
$!;;;;;;;;;;
$!  Build the form library
$!;;;;;;;;;;
$!
$ fms/library/create mega_zill mega_src:zill_browse
$!
$ fms/library/insert mega_zill mega_src:zill_entry
$ fms/library/insert mega_zill mega_src:zill_menu
$!
$ purge/log/keep=2 mega_zill
$!
$!;;;;;;;;;;
$!  Compile our code
$!;;;;;;;;;;
$!
$ basic/object=mega_obj: mega_src:basic_create_stats
$ basic/object=mega_obj: mega_src:basic_dump_drawing_data
$ basic/object=mega_obj: mega_src:basic_zill_browse
$ basic/object=mega_obj: mega_src:basic_zill_due_report
$ basic/object=mega_obj: mega_src:basic_zill_entry
$ basic/object=mega_obj: mega_src:basic_zill_import
$ basic/object=mega_obj: mega_src:basic_zill_most_report
$ basic/object=mega_obj: mega_src:basic_zill_spawn_menu
$!
$ purge/log/keep=2 mega_obj:
$!
$!;;;;;;;;;;
$!  Create our executables
$!;;;;;;;;;;
$!
$ link/exe=mega_exe: mega_obj:basic_create_stats
$ link/exe=mega_exe: mega_obj:basic_dump_drawing_data
$ link/exe=mega_exe: mega_obj:basic_zill_browse
$ link/exe=mega_exe: mega_obj:basic_zill_due_report
$ link/exe=mega_exe: mega_obj:basic_zill_entry
$ link/exe=mega_exe: mega_obj:basic_zill_import
$ link/exe=mega_exe: mega_obj:basic_zill_most_report
$ link/exe=mega_exe: mega_obj:basic_zill_spawn_menu
$!
$ purge/log/keep=2 mega_exe:
$!
$!;;;;;;;;;;
$!  Move the FDL files
$!;;;;;;;;;;
$!
$ copy mega_cms_ref:*.fdl mega_dat:*.*;0
$!
$ purge/log/keep=2 mega_dat:*.fdl
$!
$!;;;;;;;;;;
$!  Move the command files
$!;;;;;;;;;;
$!
$ copy mega_cms_ref:*.com mega_com:*.*;0
$!
$ purge/log/keep=2 mega_com:*.com
$!
$exit_program:
$ exit